'-------------------------------------------------------------- 
'Input File fitting simple analytical peak shape functions then fundamental params 
'Choose one of the following 5 peak shape descriptions
'JSOE updated 19/12/2025
'-------------------------------------------------------------- 

#define tchz_peak 
'#define uvw_peak 
'#define polynomial_peak 
'#define polynomial_peak_pv 
'#define fundamental_parameters 
 
r_wp  15.6246231 r_exp  12.050391 r_p  10.0212526 r_wp_dash  17.0916171 r_p_dash  11.2218049 r_exp_dash  13.1818008 weighted_Durbin_Watson  1.46338814 gof  1.29660715
iters 100000 
chi2_convergence_criteria 0.001 
'do_errors 
 
'Information on datafile etc here 
xdd "y2o3_fwhm_01.xye" 
	x_calculation_step = Yobs_dx_at(Xo); convolution_step 4 
	bkg @  7.56403435` -1.78956208` -0.316666202`  0.348497341` -0.0774163403`  0.130181273`
	LP_Factor(!th2_monochromator, 27.26) 
	CuKa1(0.0001) 
	Zero_Error(zero,-0.00553308023`) 
	 
	#ifdef fundamental_parameters 
		Radius(217) 
		Divergence(1) 
		axial_conv 
		filament_length         12 
		sample_length           15 
		receiving_slit_length   12 
		primary_soller_angle    5.1 
		secondary_soller_angle  5 
		Slit_Width(0.1) 
	#endif 
 
	str 
		a lpa  10.598186`) 
		b lpa  10.598186`) 
		c lpa  10.598186`) 
		al 90. 
		be 90. 
		ga 90. 
		volume  1190.405` 
		space_group "Ia-3" 
		site Y1     x 0.25          y 0.25          z 0.25          occ Y+3   1.   beq @  0.11823`
		site Y2     x 0.96764       y 0             z 0.25          occ Y+3   1.   beq @  0.05743`
		site O1     x 0.3907        y 0.1518        z 0.3801        occ O-2   1.   beq @  0.26607`
		scale @  9.7028171e-06`
		r_bragg  1.66940622
 
		#ifdef tchz_peak		 
			TCHZ_Peak_Type(pku,-0.00050572207`,pkv,  0.00222334352`,pkw, -0.00258120747`,!pkx, 0.0000,pky, 0.0919380791`,!pkz, 0.0000) 
			Simple_Axial_Model(axial, 11.3790807`) 
		#endif 
 
		#ifdef uvw_peak 
			'2. uvw peak shape 
			/*
			'excel values 
			prm !u 0.013491617 
			prm !v -0.007645516 
			prm !w 0.012172892 
			*/

			prm u  0.0150540097
			prm v -0.00966541301
			prm w  0.0139222355

			peak_type pv pv_lor 0.001 pv_fwhm = (u * Tan(Th)^2 + v * Tan(Th) + w)^0.5; 
			prm !fwhm_57 =  ((u) Tan(0.5029)^2 + (v) Tan(0.5029) + (w))^0.5; :  0.114719686
		#endif   	 
 
 
		#ifdef polynomial_peak 
			'3. simple polynomial expression 
			/*
			'excel 0.0953x2 - 0.1881x + 0.1917
			prm !cons_x2  0.0953
			prm !cons_x1  -0.1881
			prm !cons_x0  0.1917 
			*/
			prm cons_x2  0.0509425184
			prm cons_x1  -0.0970874729
			prm cons_x0  0.135453216
			gauss_fwhm =  (cons_x0 + cons_x1 (2 Th) + cons_x2 ((2 Th)^2)); 
		#endif 
 
		#ifdef polynomial_peak_pv 
		'3. simple polynomial expression 
			prm cons_x2  0.0348737582
			prm cons_x1  -0.0143056936
			prm cons_x0  0.0501748328
			peak_type pv pv_lor @  0.789219466 pv_fwhm =  (cons_x0 + cons_x1 (2 Th) + cons_x2 ((2 Th)^2)); 
			Simple_Axial_Model(axial, 10.9216925) 
		#endif 
 
		#ifdef fundamental_parameters 
			CS_L(size_lor, 329.349831) 
			Strain_G(strain_g, 0.0491299087) 
		#endif