'Input file for Simple Rietveld or Pawley refinement
r_wp  9.06889613 r_exp  10.520051 r_p  6.7691312 weighted_Durbin_Watson  0.792623665 gof  0.862058187
iters 1000
chi2_convergence_criteria 0.001
continue_after_convergence
randomize_on_errors

xdd zrwneut_sh.xy
	x_calculation_step = Yobs_dx_at(Xo); convolution_step 4
	bkg @  49.4018617`  9.61541251`  1.82146363` -4.35069888`  2.4885552` -0.899547373`
	Simple_Axial_Model(axial, 16.7258469`)
	'Neutron source description
	lam ymin_on_ymax 0.0001 la 1.0 lo 1.8857 lh 0.001
	LP_Factor(90)
	neutron_data
	Zero_Error(zero,-0.00719854103`)

	'Structural information from z:\data\topas_workshop\zrw2o8_tutorial\zrw2o8_rt.cif
	str
		a lpa  9.159106`
		b lpa  9.159106`
		c lpa  9.159106`
		al 90.      
		be 90.      
		ga 90.      
		volume  768.350`
		space_group "P213"

		'macros (name, value, reference) to refine xyz coords with +/- max_shift A min/max
		prm !max_shift 0.2 'Angstroms along each axis
		macro Nvrx(name, value, ref) {x name  value min = ref-max_shift/Get(a); max = ref+max_shift/Get(a);}
		macro Nvry(name, value, ref) {y name  value min = ref-max_shift/Get(b); max = ref+max_shift/Get(b);}
		macro Nvrz(name, value, ref) {z name  value min = ref-max_shift/Get(c); max = ref+max_shift/Get(c);}
		site Zr1 num_posns  4 Nvrx(xZr1, 0.00053`, 0.00184) y     =Get(x);:0.00053`    z  =Get(x);:0.00053`         occ Zr+4 1.0 ADPs { @  0.00884` = Get(u11); = Get(u11);  @  0.00218` = Get(u12); = Get(u12); }
		site W1  num_posns  4 Nvrx(xW1,  0.34054`, 0.34134) y     =Get(x);:0.34054`    z  =Get(x);:0.34054`         occ W+6  1.0 ADPs { @  0.01165` = Get(u11); = Get(u11);  @  0.00221` = Get(u12); = Get(u12); }
		site W2  num_posns  4 Nvrx(xW2,  0.60094`, 0.60118) y     =Get(x);:0.60094`    z  =Get(x);:0.60094`         occ W+6  1.0 ADPs { @  0.00791` = Get(u11); = Get(u11);  @  0.00160` = Get(u12); = Get(u12); }
		site O1  num_posns  12 Nvrx(xO1, 0.20658`, 0.20173) Nvry(yO1, 0.43801`, 0.44627) Nvrz(zO1, 0.44700`, 0.45557) occ O-2  1.0 ADPs { @  0.01027` @  0.02634` @  0.02689` @  0.00398` @  0.00515` @  0.00055` }
		site O2  num_posns  12 Nvrx(xO2, 0.78732`, 0.79258) Nvry(yO2, 0.56929`, 0.57034) Nvrz(zO2, 0.55611`, 0.55406) occ O-2  1.0 ADPs { @  0.00829` @  0.02149` @  0.02030` @  0.00682` @  0.00741` @  0.00275` }
		site O3  num_posns  4 Nvrx(xO3,  0.49271`, 0.49483) y     =Get(x);:0.49271`    z  =Get(x);:0.49271`         occ O-2  1.0 ADPs { @  0.02233` = Get(u11); = Get(u11);  @ -0.00898` = Get(u12); = Get(u12); }
		site O4  num_posns  4 Nvrx(xO4,  0.23362`, 0.22801) y     =Get(x);:0.23362`    z  =Get(x);:0.23362`         occ O-2  1.0 ADPs { @  0.03551` = Get(u11); = Get(u11);  @ -0.01237` = Get(u12); = Get(u12); }
		scale @  0.0472304426`
		r_bragg  1.49262024
		Phase_Density_g_on_cm3( 5.07356992`)
		phase_name zrw2o8_rt
		local CIF_PHASE_ID  1`
		'Refine sample size/strain contributions here IF TCHZ fixed to Instrumental Resolution Function
		'LVol_FWHM_CS_G_L(1, 100, 0.89, 100, csgc1, 100, cslc1, 100)
		'e0_from_Strain( 0.001, sgc1, 0.001, slc1, 0.001)



	for strs {
		TCHZ_Peak_Type(pku,-0.0162677737`,pkv,  0.0575351716`,pkw, -0.0636887992`,!pkz, 0.0000,pkx, 0.0010021556`, pky, 0.023755593`)
	}

'Out_pdCIF(pdCIFplotter.cif, "proc")